Advent of Code 2015 - Day 5: Doesn't He Have Intern-Elves For This?

Part 1

Description

Santa needs help figuring out which strings in his text file are naughty or nice.
A nice string is one with all of the following properties:

• It contains at least three vowels (aeiou only), like aei, xazegov, or aeiouaeiouaeiou.
• It contains at least one letter that appears twice in a row, like xx, abcdde (dd), or aabbccdd (aa, bb, cc, or dd).
• It does not contain the strings ab, cd, pq, or xy, even if they are part of one of the other requirements.

For example:

• ugknbfddgicrmopn is nice because it has at least three vowels (u...i...o...), a double letter (...dd...), and none of the disallowed substrings.
• aaa is nice because it has at least three vowels and a double letter, even though the letters used by different rules overlap.
• jchzalrnumimnmhp is naughty because it has no double letter.
• haegwjzuvuyypxyu is naughty because it contains the string xy.
• dvszwmarrgswjxmb is naughty because it contains only one vowel.

How many strings are nice?

Input

Solution

So, there are three conditions to be met for a string to be nice. Therefore, in my Excel file, after putting the input in the leftmost column, I put these condition in the adjacent columns.

Column C is for counting the number of vowels, using this formula:

=LEN(A3)-LEN(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A3,"a",""),"e",""),"i",""),"o",""),"u",""))

Column D is for counting any double letter, using this array formula:

=SUM(IF(MID($A3,(ROW(INDIRECT("1:"&LEN($A3)))),1)=MID($A3,1+(ROW(INDIRECT("1:"&LEN($A3)))),1),1,0))

Column E is for counting any special condition above, using this formula:

=LEN(A3)-LEN(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A3,"ab",""),"cd",""),"pq",""),"xy",""))

Now, what is left is counting how many strings fulfill these conditions.

Part 2

Description

Realizing the error of his ways, Santa has switched to a better model of determining whether a string is naughty or nice. None of the old rules apply, as they are all clearly ridiculous.
Now, a nice string is one with all of the following properties:

• It contains a pair of any two letters that appears at least twice in the string without overlapping, like xyxy (xy) or aabcdefgaa (aa), but not like aaa (aa, but it overlaps).
• It contains at least one letter which repeats with exactly one letter between them, like xyx, abcdefeghi (efe), or even aaa.

For example:

• qjhvhtzxzqqjkmpb is nice because is has a pair that appears twice (qj) and a letter that repeats with exactly one letter between them (zxz).
• xxyxx is nice because it has a pair that appears twice and a letter that repeats with one between, even though the letters used by each rule overlap.
• uurcxstgmygtbstg is naughty because it has a pair (tg) but no repeat with a single letter between them.
• ieodomkazucvgmuy is naughty because it has a repeating letter with one between (odo), but no pair that appears twice.

How many strings are nice under these new rules?

Solution

For the part two, the conditions have changed. So I just added two more columns. Column H is for counting instances of two letters appear twice, using array formula:

=SUM(LEN(A3)-LEN(SUBSTITUTE($A3,MID($A3,(ROW(INDIRECT("1:"&LEN($A3)-1))),2),"")))

If the result is 30, it means there is no instance of two letters appear twice. Each string in the input is exactly 16 character long. So, there will be 15 pairings. When one of these pairs (for example, xy) matches with itself, the formula will return a value of two (and total of 30 for the whole string). When it matches another pair, the formula will return another value of two. So, when the result is more than 30, it means that string contains two letters that appear more than once.
Column I is for counting if there is any letter which repeats with exactly one letter between them, using array formula:

=SUM(IF(MID($A3,(ROW(INDIRECT("1:"&LEN($A3)))),1)=MID($A3,2+(ROW(INDIRECT("1:"&LEN($A3)))),1),1,0))

And again, all I need is counting how many strings fulfill these conditions.